凪司工房の徒然

# Declare images below this line, using the image statement.←画像定義
# 背景
image bg castle = "img/gyokuza.png"
image bg bar = "img/sakaba.png"
image bg inn = "img/yado.png"
image bg forest = "img/mori.png"
image bg ma_castle = "img/maoujou.png"
# 人物
image king = "img/king.png"
image soldier = "img/soldier.png"
image hero = "img/yusha.png"
image witch = "img/witch.png"
image priest = "img/priest.png"
image innman = "img/yadofu.png"
image maou = "img/maou.png"

# You can place the script of your game in this file.

# Setting Japanese
init:
    $ style.default.font = "VL-PGothic-Regular.ttf"
    $ style.default.language = "eastasian" # 日本語禁則処理

# Declare images below this line, using the image statement.←画像定義
# 背景
image bg castle = "img/gyokuza.png"
image bg bar = "img/sakaba.png"
image bg inn = "img/yado.png"
image bg forest = "img/mori.png"
image bg ma_castle = "img/maoujou.png"
# 人物
image king = "img/king.png"
image soldier = "img/soldier.png"
image hero = "img/yusha.png"
image witch = "img/witch.png"
image priest = "img/priest.png"
image innman = "img/yadofu.png"
image maou = "img/maou.png"

# Declare characters used by this game.←名前定義だよ
define king = Character('王', color="#ff9900")
define soldier = Character('兵士', color="#009900")
define u = Character('勇者', color="#0000ff")
define wiz = Character('魔法使い', color="#ffdd00")
define pre = Character('僧侶', color="#ff00ff")
define inn = Character('宿夫')
define M = Character('魔王', color="#9900ff")

# The game starts here.
label start:
    scene black
    "この物語は一人の魔王と、一人の勇者の、汗と涙と血と骨と肉の物語である。"
    "この国では国民から魔王と戦う勇者を選出し、永きに渡り魔王と戦ってきた。"
    scene bg castle
    show king at left
    show soldier at right
    king "次の勇者はこの者だ。探し出してここに連れてこい！"
    soldier "承知しました！"
    scene black
    "こうして第156代目の勇者にあなたは選出されたのである。"
    scene bg castle
    show king at left
    show hero at right
    u "えっと、何すか？"
    king "お前は第156代目の勇者に選ばれたのだ。さっさと魔王と戦って世界平和を取り戻せ！"
    u "えー、そんな面倒な。"
    king "もし魔王を倒したらその暁には何なりと望みを叶えよう。"
    u "よしわかった。商談成立だな。"
    king "では手続きを済ませて、さっさと魔王討伐の旅へ出ろ。"
    u "もし俺が魔王を倒して帰ってきたら、まずお前のその命令口調なおしてやっからな。"
    scene black
    "こうして勇者は旅の準備をしに酒場へ向かった。"
    
    jump sakaba

label sakaba:
    scene bg bar
    "酒場にやってきた勇者だったが、そこで勇者は二人のよく知る女性を見かける。"
    "一人は今付き合っている彼女の金髪の魔法使いだ。"
    show witch at left
    "もう一人は寂しそうにバーカウンターに座っている元彼女の紫髪の僧侶。"
    show priest at right
    
    "あなたはどちらに話しかける？"
    menu:
        "今の彼女の金髪の魔法使い":
            hide priest
            $ girl_friend = 1
            jump ima_kano
        "昔の彼女の紫髪の僧侶":
            hide witch
            $ girl_friend = 2
            jump moto_kano

label ima_kano:
    show hero at right
    u "飲みにくるなんて珍しいな。"
    wiz "あんた、私を置いて旅に出るつもりだったんでしょ？"
    u "危険な旅に連れてけないよ。"
    wiz "この前ずっと一緒にいようって言ってたじゃない！"
    u "酔ってたんだよ。"
    wiz "死ぬ時は一緒だから。"
    u "何言うんだよ、縁起悪いな。"
    wiz "私、一緒に行くから。"
    "魔法使いが仲間になった！"
    
    jump trip1

label moto_kano:
    show hero at left
    u "久しぶり、だな。"
    pre "あ……。勇者に選ばれたんだよね？"
    u "ああ。世界を救うことになっちまった。"
    pre "あの頃言ってたホラが、叶っちゃったね。"
    u "最近はどうなんだよ？"
    pre "どうって……別に。"
    u "また悪い男につかまってんじゃないのかよ。"
    pre "だったら何？"
    u "もうやめろよ、そういうの。"
    pre "じゃあ、勇者と一緒に冒険の旅に出ちゃおうかな。"
    u "……いいぜ。"
    pre "ほんとに？　ほんとのほんと？"
    u "ああ。"
    "僧侶が仲間になった！"
    
    jump trip1

label trip1:
    scene black
    "勇者は仲間と共に魔王討伐の旅に出かけた。"
    "行く先々で魔王の配下に苦しめられている町や村を救いながら、進んだ。"
    "とある村に泊まった夜のことだった。"
    
    jump shuraba

label shuraba:
    if girl_friend == 1:
        jump shuraba_imakano
    if girl_friend == 2:
        jump shuraba_motokano

label shuraba_imakano:
    scene bg inn
    show witch at left
    show hero at right
    u "何だよ、話って？"
    wiz "あのね……アレが、ないの。"
    u "何か前の村に忘れ物か？"
    wiz "ソレがさ、きちゃったみたいなの。"
    u "忘れ物が？　歩いてきたのか？"
    wiz "お前の赤ん坊が出来たって言ってんだよ！"
    u "えっと……マジか？"
    wiz "結婚する？　ねえ結婚しちゃう？"
    menu:
        "はい":
            scene black
            "翌日、勇者と魔法使いは村で小さな式を挙げた。"
            "こうして二人は冒険の旅から新婚旅行へとその目的を切り替えた。"
            jump ending
        "いいえ":
            scene black
            "翌日、勇者の撲殺死体が発見された。"
            "犯人は見つかっていないが、王国では既に次の勇者選考が行われているそうだ。"
            jump ending

label shuraba_motokano:
    scene bg inn
    show hero at left
    u "あれ？　僧侶どこ行ったんだ？"
    scene bg forest
    show priest at right
    show innman
    "勇者が宿の外に出てみると、そこでは僧侶と宿屋の息子が抱き合っていた。"
    show hero at left
    u "おい！　何してんだ！"
    pre "あ、勇者。ごめん……。"
    u "ごめんじゃなくて何か言えよ。"
    inn "彼女は悪くない。オレが、宿屋を継がずにいれば……。"
    pre "彼と、付き合ってたの……。"
    u "ごめんじゃなくて何か言えよ。"
    inn "……。"
    pre "……。"
    u "何なんだよ！　これじゃ俺が悪者じゃないか！"
    "宿屋の息子をぶち殺しますか？"
    menu:
        "はい":
            scene black
            "宿屋の息子は意外と強かった。"
            "敗れた勇者は一人寂しく、傷心の旅へと出かけたが、"
            "勇者のその後を知る者は誰もいない。"
            jump ending
        "いいえ":
            scene black
            "翌朝、勇者はひっそりと村を出て行った。"
            "僧侶と宿屋の息子の毒殺死体が見つかったが、その犯人はまだ見つかっていない。"
            jump ending

label ending:
    scene black
    "一方その頃、魔王の城では……"
    scene bg ma_castle
    show maou
    M "勇者君まだ来ないの？　もう待ちくたびれちゃったよお。"
    "魔王はそのあまりの退屈さに一億と三千二百六十四回目の欠伸をかみ殺した。"
    
    "END"
    return